I use a custom git diff driver with a simple textconv script for better diffs.
It does the following:
- Sort the file using a version sort - for the most part the file is already sorted, but it uses a simple sort (0, 1, 10, 11, ..., 19, 2, 20) that results in the order of the Mcu.IPX and MCU.PinX entries changing when one gets added.
- Remove the number from the Mcu.IPX and MCU.PinX entries so they don't all change when you turn on a new pin/module.
- Put each comma separated IPParameters\GPIOParameters\RequestParameters value on its own line and sort them
- Put each comma separated ProjectManager.functionlistsort value on its own line
Note that the output is no longer a valid IOC file. It's for generating diffs only.
User .gitconfig:
[diff "cubemx"]
textconv = git_textconv_cubemx.sh
Repo .gitattributes:
*.ioc diff=cubemx
git_textconv_cubemx.sh:
#!/bin/bash
sort --version-sort $1 | gawk '
/^Mcu\.IP[0-9]+=/ { sub(/^Mcu\.IP[0-9]+=/, "Mcu.IP="); print; next }
/^Mcu\.Pin[0-9]+=/ { sub(/^Mcu\.Pin[0-9]+=/, "Mcu.Pin="); print; next }
/\.(IP|Request|GPIO)Parameters=/ {
eq = index($0, "=");
print substr($0, 1, eq);
split(substr($0, eq + 1), values, ",");
asort(values);
for (i in values) print "\t" values[i];
next }
/^ProjectManager\.functionlistsort=/ {
eq = index($0, "=");
print substr($0, 1, eq);
split(substr($0, eq + 1), values, ",");
for (i in values) print "\t" values[i];
next; }
{ print }
'
