STM32H753IIT6 HEX File Generation erroneously includes RAM sections

[MPete.3]

Hello,

We are having an issue with the STM32H753IIT6, which contains several RAM sections... namely ITCMRAM (0x00000000), DTCMRAM (0x20000000), RAM_D1 (0x24000000), RAM_D2 (0x30000000), RAM_D3 (0x38000000).

The problem that is occurring: When loading variables specifically into RAM_D2 and RAM_D3 (0x30000000), the generated Hex file is including this section as a loadable section, which in turn causes issues in STM32CubeProgrammer when it tries to load that section. When the (NOLOAD) option is applied to the linker script, it does fix the problem, however we do not like this option as we then have to specially treat any initial values in the code...

Is this a known issue?

/*
******************************************************************************
**
**  File        : LinkerScript.ld
**
**  Author      : STM32CubeIDE
**
**  Abstract    : Linker script for STM32H7 series
**                2048Kbytes FLASH and 1056Kbytes RAM
**
**                Set heap size, stack size and stack location according
**                to application requirements.
**
**                Set memory bank area and size if external memory is used.
**
**  Target      : STMicroelectronics STM32
**
**  Distribution: The file is distributed as is, without any warranty
**                of any kind.
**
*****************************************************************************
** @attention
**
** Copyright (c) 2022 STMicroelectronics.
** All rights reserved.
**
** This software is licensed under terms that can be found in the LICENSE file
** in the root directory of this software component.
** If no LICENSE file comes with this software, it is provided AS-IS.
**
****************************************************************************
*/
 
/* Entry Point */
ENTRY(Reset_Handler)
 
/* Highest address of the user mode stack */
_estack = ORIGIN(RAM_D1) + LENGTH(RAM_D1);    /* end of RAM */
_Application = ORIGIN(FLASH);
_BootArgsAddress = ORIGIN(BOOTARGS);
_FlashValidationAddress = ORIGIN(FLASH_VALIDATION);
/* Generate a link error if heap and stack don't fit into RAM */
_Min_Heap_Size = 0x800 ;      /* required amount of heap  */
_Min_Stack_Size = 0x800 ; /* required amount of stack */
 
/* Specify the memory areas */
MEMORY
{
  FLASH (rx)			: ORIGIN = 0x08000000								, LENGTH = 2048K - 2K - 128K
  FLASH_VALIDATION (rx) : ORIGIN = ORIGIN(FLASH) + LENGTH(FLASH)			, LENGTH = 2K
  AES (r)				: ORIGIN = ORIGIN(FLASH_VALIDATION) + LENGTH(FLASH_VALIDATION), LENGTH = 128K
  DTCMRAM (xrw)  		: ORIGIN = 0x20000000								, LENGTH = 128K
  RAM_D1 (xrw)   		: ORIGIN = 0x24000000								, LENGTH = 512K
  RAM_D2 (xrw)   		: ORIGIN = 0x30000000								, LENGTH = 288K
  RAM_D3 (xrw)   		: ORIGIN = 0x38000000								, LENGTH = 64K - 32
  BOOTARGS (xrw) 		: ORIGIN = ORIGIN(RAM_D3) + LENGTH(RAM_D3)			, LENGTH = 32
  RAM_BACKUP (xrw)		: ORIGIN = 0x38800000								, LENGTH = 4K
  ITCMRAM (xrw)  		: ORIGIN = 0x00000000								, LENGTH = 64K
}
 
/* Define output sections */
SECTIONS
{
  /* The startup code goes first into FLASH */
  .isr_vector :
  {
    . = ALIGN(4);
    _vector_table_address_start = .;
    KEEP(*(.isr_vector)) /* Startup code */
    . = ALIGN(4);
  } >FLASH
  
  .bootargs(NOLOAD) :
  {
  	. = ALIGN(4);
  	KEEP(*(.bootargs))
  	. = ALIGN(4);
  } >BOOTARGS
  
    .aes :
  {
    . = ALIGN(4);
    *(.aes)
    *(.aes*)
    . = ALIGN(4);
  } >AES
  
   .flash_validation :
  {
  	. = ALIGN(4);
  	KEEP(*(.flash_validation))
  	. = ALIGN(4);
  } >FLASH_VALIDATION
  
  .ram2section :
  {
  	. = ALIGN(4);
  	KEEP(*(.ram2section))
  	. = ALIGN(4);
  } >RAM_D2
  
  .ram3section :
  {
  	. = ALIGN(4);
  	KEEP(*(.ram3section))
  	. = ALIGN(4);
  } >RAM_D3
  
  .ramBackupSection :
  {
  	. = ALIGN(4);
  	KEEP(*(.ramBackupSection))
  	. = ALIGN(4);
  } >RAM_BACKUP
 
  /* The program code and other data goes into FLASH */
  .text :
  {
    . = ALIGN(4);
    *(.text)           /* .text sections (code) */
    *(.text*)          /* .text* sections (code) */
    *(.glue_7)         /* glue arm to thumb code */
    *(.glue_7t)        /* glue thumb to arm code */
    *(.eh_frame)
 
    KEEP (*(.init))
    KEEP (*(.fini))
 
    . = ALIGN(4);
    _etext = .;        /* define a global symbols at end of code */
  } >FLASH
 
  /* Constant data goes into FLASH */
  .rodata :
  {
    . = ALIGN(4);
    *(.rodata)         /* .rodata sections (constants, strings, etc.) */
    *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
    . = ALIGN(4);
  } >FLASH
 
  .ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
  .ARM : {
    __exidx_start = .;
    *(.ARM.exidx*)
    __exidx_end = .;
  } >FLASH
 
  .preinit_array     :
  {
    PROVIDE_HIDDEN (__preinit_array_start = .);
    KEEP (*(.preinit_array*))
    PROVIDE_HIDDEN (__preinit_array_end = .);
  } >FLASH
 
  .init_array :
  {
    PROVIDE_HIDDEN (__init_array_start = .);
    KEEP (*(SORT(.init_array.*)))
    KEEP (*(.init_array*))
    PROVIDE_HIDDEN (__init_array_end = .);
  } >FLASH
 
  .fini_array :
  {
    PROVIDE_HIDDEN (__fini_array_start = .);
    KEEP (*(SORT(.fini_array.*)))
    KEEP (*(.fini_array*))
    PROVIDE_HIDDEN (__fini_array_end = .);
  } >FLASH
 
  /* used by the startup to initialize data */
  _sidata = LOADADDR(.data);
 
  /* Initialized data sections goes into RAM, load LMA copy after code */
  .data :
  {
    . = ALIGN(4);
    _sdata = .;        /* create a global symbol at data start */
    *(.data)           /* .data sections */
    *(.data*)          /* .data* sections */
    *(.RamFunc)        /* .RamFunc sections */
    *(.RamFunc*)       /* .RamFunc* sections */
 
    . = ALIGN(4);
    _edata = .;        /* define a global symbol at data end */
  } >RAM_D1 AT> FLASH
 
  /* Uninitialized data section */
  . = ALIGN(4);
  .bss :
  {
    /* This is used by the startup in order to initialize the .bss section */
    _sbss = .;         /* define a global symbol at bss start */
    __bss_start__ = _sbss;
    *(.bss)
    *(.bss*)
    *(COMMON)
 
    . = ALIGN(4);
    _ebss = .;         /* define a global symbol at bss end */
    __bss_end__ = _ebss;
  } >RAM_D1
 
  /* User_heap_stack section, used to check that there is enough RAM left */
  ._user_heap_stack :
  {
    . = ALIGN(8);
    PROVIDE ( end = . );
    PROVIDE ( _end = . );
    . = . + _Min_Heap_Size;
    . = . + _Min_Stack_Size;
    . = ALIGN(8);
  } >RAM_D1
 
  /* Remove information from the standard libraries */
  /DISCARD/ :
  {
    libc.a ( * )
    libm.a ( * )
    libgcc.a ( * )
  }
 
  .ARM.attributes 0 : { *(.ARM.attributes) }
}
 
 

Thanks,

Marshall

[waclawek.jan]

In the GNU environment (gcc, binutils/ld) if you want to place both explicitly initialized and initialized-as-zero variables into a piece of memory, you have to manually assign them to different sections, and then place both those sections into given memory, one of the tagged noload. You of course have also to write the appropriate initializations into the startup code.

The automatic split between explicitly and implicitly-initialized-as-zero variables (into .data and .bss, respectively) is provided only for the default memory.

JW

[Tesla DeLorean · Accepted solution]

Inspect .MAP file, or dump .ELF with OBJCOPY or FROMELF type tools, determine what you're not managing properly in the .LD file

The handling on initialization ST provides in startup.s is rather naive, Keil has a more table managed scatter loader, and the Arduino GNU guys also seem a lot more on the ball with regard to the startup code, and generating tables for copying and zeroing data out of multiple sections, into multiple memory ranges. Might want to look that over for ideas/clarity.

Typically in situations where you have initialized data in RAM, you need to park that in FLASH so you can copy it out during startup. ST fishes it out via labels

1. } >RAM_D1 AT> FLASH

[MPete.3]

Thanks for the info!

I was able to resolve the issue by adding AT> FLASH to both the >RAM_D2 and >RAM_D3 section declarations.

[FBL]

Hi @MPete.3​ ,

I am interested to reproduce the issue but wasn't able to do it on my environment STM32CubeIDE Version: 1.10.1 STM32CubeProgrammer v2.11.0

Could you please 

1- Precise the version of cube Programmer you are using

2- Precise the version of cube IDE

3- Share a minimum piece of project that can help me reproduce the issue

Thanks